"Up Your Sleeve" by chrisamaphone

Release along with the source text.
Use no scoring.
Use full-length room descriptions.

When play begins:
say
"It's the evening of your debut stage magic performance. You, Magnificent Max, are the opening act for the Fabulous Flying Funambulists, a troupe of world-class acrobats! Your great uncle, a retired once-renowned magician himself, set you up with the act, and you'd better not screw it up -- this is your chance to make it big.

Unfortunately, the audience is in a bit of a hostile mood: the host has just announced that the main act was canceled. The burden is on your shoulders to deliver to them a show comparable to the one that they paid for."

The description of the player is
"You're Magnificent Max, magician-in-training. Your (off-)white ruffled shirt is (mostly) tucked in to (slightly scuffed) black slacks. These clothes, handed down from your esteemed great-uncle, hang loosely on your gaunt frame. You gelled your hair back this morning, but it is now slightly ruffled, and that one horrendous ungelled lock you can't keep down sprouts over your brow, obscuring your sight and betraying your unruly curls."

The player carries a deck of cards.
	The cards can be shuffled or sorted.
	The cards are sorted.
	The description of the cards is "Your lucky deck."
	Instead of examining the cards when the scene is stage show and card-transformation is unperformed:
		say "You remember your great uncle teaching you a trick to magically sort a deck of cards."
	Shuffling is an action applying to one thing.
	Understand "shuffle [something]" as shuffling.
	Instead of shuffling the cards:
		say "You shuffle the cards idly.";
		now the cards are shuffled.
	[Understand "shuffle" as shuffling.
	Instead of shuffling nothing, say "You shuffle your feet a little."]
	
The player carries a magic wand.
	The description of the wand is "Your magician's baton."
	Instead of waving the wand, say "You wave your wand, say a magic word, and pretend that something awesome happens. You always did have a good imagination."
	
The player wears the pair of shoes.
	The description of the shoes is "Shiny and new. You can't help but groom yourself a little as you glimpse your reflection: you slick your hair back, grin, notice the grime on your teeth, and rub them with your finger to no avail. After a second, the curly lock you slicked back springs back into your eyes."
	
[----------- Stage Show --------------]
Stage Show is a scene.
Stage Show begins when play begins.
Tricks done is a number that varies. Tricks done is 0.
Stage Show ends when tricks done is 3.

[ Setup for this scene]
The Stage is a room. "A bare wooden stage. The curtains are raised, exposing you to the vast audience murmuring in front of you. The spotlight and tower lights shine hotly into your eyes, making you blink and sweat."

The table is a supporter in the stage. The table is fixed in place.
The description is "The table is long, narrow, and felt-covered: perfect for setting up magic props and tricks."
After examining the table when something is on the table:
	say "On the table [is-are a list of things on the table].".
Rule for writing a paragraph about the table:
	say "In front of you is a table for your magical props."

A hat is a wearable container. The description is "Standard issue black top hat."
After examining the hat when something is in the hat:
	say "The hat contains [a list of the things contained by the hat].".
Understand "top hat" as the hat.
The hat is on the table.

A rabbit is a kind of animal.
Alice is a female rabbit. The description of Alice is "She's Alice, your beloved pet rabbit. Small, white, curiouser, and curiouser."
Understand "rabbit" as Alice. 
Alice is on the table.
Instead of taking Alice:
	say "Alice reluctantly allows you to scoop her up.";
	move Alice to the player.
Instead of taking Alice when the scene is stage show and Alice is in the hat:
	say "Pulling a rabbit out of a hat isn't a very good trick when they saw you put her in."
Instead of attacking Alice when the scene is not Stage Show:
	say "You'd never hurt your beloved pet."
Instead of eating Alice when the scene is not Stage Show:
	say "You never cared for rabbit, actually."
Petting is an action applying to one thing.
Understand "pet [something]" as petting.
Instead of petting Alice, say "You scratch Alice affectionately behind the ears."
	
A retractable sword is on the table. The description is "It looks so real! ...sort of."

There is a tomato. "Plump, juicy, and rotten."

Instead of wearing a container when something is in the noun, say "You'd better remove [the list of things in the noun] first."

The stageitself is scenery in the stage.
Understand "stage" as the stageitself.
The printed name of the stageitself is the "stage".
Instead of examining the stageitself, say "Bare polished wood."
The curtains are scenery in the stage. Instead of examining the curtains, say "Heavy blue curtains."
The lights are scenery in the stage. Instead of examining the lights, say "Blindingly bright."
Understand "spotlight" as the lights.
The audience is scenery in the stage. Instead of examining the audience, say
"The house is packed with audience members who fled from across the nation to see the Fabulous Flying Funambulists. Instead, they get you. And they don't look happy about it."
The props are scenery in the stage.
Instead of examining the props:
	try examining the table.

[Doing tricks]

Trickdoing is an action applying to nothing.
Understand "do trick" as trickdoing.
Instead of trickdoing, say "Yes, but which one?"

A trick is a kind of thing. A trick can be performed or unperformed.
Sword-swallowing is a trick. Sword-swallowing is unperformed.
Rabbit-be-gone is a trick. Rabbit-be-gone is unperformed.
Card-transformation is a trick. Card-transformation is unperformed.
Levitation is a trick. Levitation is unperformed.

Performing something is an activity.
	
Rule for performing a performed trick:
	Say "You'd rather not try that trick again.";
	Stop the action.

Descperfing something is an activity.
Rule for descperfing levitation:
	say "Aha! The levitation trick!
	
	You leap into the air, meanwhile realizing that your great uncle never actually finished teaching you this trick. Instead, you face plant into the stage."
Rule for descperfing sword-swallowing:
	say "Aha! The sword swallowing trick!
	
	You poise the sword above your open mouth, prepared to terrify and bewilder the audience -- when suddenly the sword fully retracts before the trick begins."
Rule for descperfing rabbit-be-gone:
	say "Aha! The rabbit-be-gone trick!
		
	You wave the wand over the hat, then, after a dramatic pause, flip it over -- only to find Alice clinging to the inside. She pokes her head out the false top of the hat and looks up at you innocently before hopping out onto the table.";
	now Alice is on the table.
Rule for descperfing card-transformation:
	say "Aha! The card transformation trick!
			
	You wave your wand over the cards, then pause for effect. As you reach to present the deck to the audience, several double-sided cards fall from your sleeves. You dart in a panic to restore them, but in doing so, knock the deck from the table. Cards flutter in every direction around you.";
	move the cards to the stage.
Instead of examining the cards when the cards are on the stage,
	say "Your cards are scattered about."
Instead of taking the cards when the cards are on the stage:
	say "You play 52-card pickup. The audience is not amused.";
	move the cards to the player.
	
After performing an unperformed trick (called the magictrick):
	carry out the descperfing activity with the magictrick;
	now the magictrick is performed;
	change tricks done to tricks done plus one.

[
	"You catch sight of a particularly angry man with a heavy round face and a handlebar mustache hail a tomato salesman."
	]

[Audience reactions to tricks]
Every turn when tricks done is zero,
	say "The audience murmurs impatiently."
Every turn when tricks done is one,
	say "The audience stirs and titters nervously."
Every turn when tricks done is two, 
	say "The audience grows increasingly restless and angry."
[Clusters of people are making their way to the exits; the rest are shouting insults. ]
	
Understand "swallow [something]" as eating.
Instead of eating the sword when the scene is stage show:
	carry out the performing activity with sword-swallowing;
	
Instead of jumping when the scene is stage show:
	carry out the performing activity with levitation.
Understand "fly" as jumping.
Understand "levitate" as jumping.

Instead of waving the wand when the scene is stage show:
	If Alice is in the hat:
		carry out the performing activity with rabbit-be-gone;
	Otherwise:
		If the cards are shuffled and the cards are on the table:
			carry out the performing activity with card-transformation;
		Otherwise:
			say "Maybe you should set up a trick first."
		
Instead of shuffling the cards when the scene is stage show:
	say "You shuffle the cards and spread them out on the table.";
	now the cards are shuffled;
	move the cards to the table.

Instead of singing when the scene is stage show:
	say "That's not really the particular talent you're here to display."
Dancing is an action applying to nothing. Understand "dance" as dancing.
Instead of dancing when the scene is stage show:
	say "That's not really the particular talent you're here to display."

[Ending of this scene]
When Stage Show ends:
	Say "[line break]With horror, out of the corner of your eye, you catch sight of a red fist-sized object sailing towards your face. You brace yourself for impact, squeezing your eyes shut... [italic type]it's all over now, all your hopes and dreams...[roman type][line break]	
	
Suddenly, everything goes quiet. Cautiously, you open your eyes. You can hardly believe them: hovering inches from your nose is a perfectly still tomato.[line break]

Before you have time to react, a flash of white light floods your vision, accompanied by a deafening roar. And you begin to rise off the stage. This is no levitation illusion. You look above you to identify the source of the trick, but all you can see is blinding light. As you blink the spots from your eyes, you see the tomato, your top hat, and your rabbit Alice making the smooth ascent alongside you. Alice looks at you with wide, dumb eyes. [line break]

	You hear a hatch open above you just as your senses fade.[line break]";
	end the game saying
	"[italic type]Tune in next week for the next chapter![roman type]".[;
	move the tomato to the player;
	move the hat to the player;
	move the player to the Prisoner's Quarters;
	move Alice to the Captain's Bay. [XXX change?]]

[ XXX write for next week

[----------- Prisoner's Quarters ------------]
Escape is a scene.

The Prisoner's Quarters is a room. 
"You are in a square, bare room with metal walls."

The hatch is a closed door. It is not lockable.
The hatch is north of the prisoner's quarters.
Instead of examining the hatch when the hatch is closed, say
"It's round and consists of several radial interlocking plates.

You can't believe the nerve of them locking you in here."

Before eating something while in the prisoner's quarters: say "You're not that desperate yet."; stop the action.

Instead of opening the hatch, say "You struggle and pry at the interlocking plates, achieving nothing."

A wall is a kind of supporter. It is usually scenery.
The east wall, south wall, and west wall are walls in the prisoner's quarters.
Understand "walls" as a wall.
Instead of examining the west wall, say "A cold, bare steel wall."
Instead of examining the south wall, say "A cold, bare steel wall."
Instead of examining the east wall, say "You see a keypad here."
Instead of examining west when in the prisoner's quarters, try examining the west wall.
Instead of examining south when in the prisoner's quarters, try examining the south wall.
Instead of examining east when in the prisoner's quarters, try examining the 
east wall.
Instead of examining north when in the prisoner's quarters, try examining the hatch.

The ceiling is scenery in the prisoner's quarters. "You see a vent."
The vent is part of the ceiling.

Instead of examining up when in the prisoner's quarters, try examining the ceiling.

The keypad is a thing on the east wall.
The description of the keypad is 
"The keypad has four buttons: red, yellow, green, and blue."
The keypad is fixed in place.

A keybutton is a kind of thing.
The red button is a keybutton that is part of the keypad.
The yellow button is a keybutton that is part of the keypad.
The green button is a keybutton that is part of the keypad.
The blue button is a keybutton that is part of the keypad.

After pushing a keybutton for the fourth time, say "BOO!"

[Captain's Bay]

The Captain's Bay is a room.]